<%
MouseOverExt = "NAVY"
MouseOverInt = "NAVY"
MouseOut = "DARKGREEN"
%>
<SCRIPT LANGUAGE="VBScript">
    Option Explicit
    
    Sub clickHandler()

        Dim i
        Dim strParentId
        Dim objChild
        Dim objParentImage
        Dim sDisplay
        Dim sImage

        '== Identify the item clicked
        strParentId = Window.Event.SrcElement.ID
        If Left(strParentId, 1) = "M" Then
            '== Identify child DIV and parent IMG objects
            Set objChild = Document.All("C" & Mid(strParentId, 3))
            Set objParentImage = Document.All("MI" & Mid(strParentId, 3))
            '== manipulate their attributes
            If objChild.Style.Display = "none" Then
                objChild.Style.Display = ""
                objParentImage.Src = "booko.gif"
            Else
                objChild.Style.Display = "none"
                objParentImage.Src = "bookc.gif"
            End If
            Set objChild = Nothing
            Set objParentImage = Nothing
        ElseIf Left(strParentId, 3) = "ALL" Then
            If Mid(strParentId, 4) = "Expand" Then
                sDisplay = ""
                sImage = "booko.gif"
            Else
                sDisplay = "none"
                sImage = "bookc.gif"
            End If
            For i = 0 To Document.All.Length - 1
                If Left(Document.All(i).ID, 1) = "C" Then
                    Document.All(i).Style.Display = sDisplay
                End If
                If Left(Document.All(i).ID, 2) = "MI" Then
                    Document.All(i).Src = sImage
                End If
            Next
        End If

    End Sub


    Sub mouseOverHandler()

        If Window.Event.SrcElement.TagName = "A" Or _
           Left(Window.Event.SrcElement.ID, 2) = "MT" Or _
           Left(Window.Event.SrcElement.ID, 3) = "ALL" _
           Then
            If Window.Event.SrcElement.ID = "EXTERNAL" Then
                Window.Event.SrcElement.Style.Color = "<% =MouseOverExt %>"
            Else
                Window.Event.SrcElement.Style.Color = "<% =MouseOverInt %>"
            End If
        ElseIf Left(Window.Event.SrcElement.ID, 2) = "MI" Then
            If Document.All("MT" & Mid(Window.Event.SrcElement.ID, 3)).ID = "EXTERNAL" Then
                Document.All("MT" & Mid(Window.Event.SrcElement.ID, 3)).Style.Color = "<% =MouseOverExt %>"
            Else
                Document.All("MT" & Mid(Window.Event.SrcElement.ID, 3)).Style.Color = "<% =MouseOverInt %>"
            End If
        End If

    End Sub

    Sub mouseOutHandler()

        If Window.Event.SrcElement.TagName = "A" Or _
           Left(Window.Event.SrcElement.ID, 2) = "MT" _
           Then
            Window.Event.SrcElement.Style.Color = "<% =MouseOut %>"
        ElseIf Left(Window.Event.SrcElement.ID, 3) = "ALL" Then
            Window.Event.SrcElement.Style.Color = "<% =MouseOut %>"
        ElseIf Left(Window.Event.SrcElement.ID, 2) = "MI" Then
            Document.All("MT" & Mid(Window.Event.SrcElement.ID, 3)).Style.Color = "<% =MouseOut %>"
        End If

    End Sub

</SCRIPT>