<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html"/>
  <xsl:param name="class"/>
  <xsl:template match="/*">
    <xsl:apply-templates select="root" />
  </xsl:template>
  <xsl:template match="root">
    <ul class="{$class}">
      <xsl:apply-templates select="node" />
    </ul>
  </xsl:template>
  <xsl:template match="node">
    <li>
      <xsl:if test="@breadcrumb = 1">
        <xsl:attribute name="class">active</xsl:attribute>
      </xsl:if>

      <xsl:variable name="url">
        <xsl:choose>
          <xsl:when test="@enabled = 1">
            <xsl:value-of select="@url"/>
          </xsl:when>
          <xsl:otherwise>#</xsl:otherwise>
        </xsl:choose>
      </xsl:variable>

      <a href="{$url}">
        <xsl:if test="@breadcrumb = 1">
          <xsl:attribute name="class">active</xsl:attribute>
        </xsl:if>
        <xsl:if test="string-length(@icon) > 0">
          <img alt="{@text}" src="{@icon}" />
        </xsl:if>
        <xsl:value-of select="@text" />
      </a>
      <xsl:if test="node">
        <ul>
          <xsl:if test="@breadcrumb = 1">
            <xsl:attribute name="class">active</xsl:attribute>
          </xsl:if>
          <xsl:apply-templates select="node" />
        </ul>
      </xsl:if>
    </li>
  </xsl:template>
</xsl:stylesheet>